***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar. 25, 2026                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5538S6VC-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs     s1    s2    205u TC=3m
Rg     g1    g2    2.156
M1     d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=850  VTO=4.1  LEVEL=3  VMAX=5e4 NFS=8e11  GAMMA=1.8)
Rd     d1    d2    5.500e-4    TC=2.5e-3,10u
Dbd    s2    d2    Dbt
.MODEL Dbt   D   (IS=2.036e-12   N=9.539e-1  RS=5.000e-4  EG=1.120  TT=20n  TRS1=-5.500e-3
+                 BV=44  TBV1=4.535e-4 TBV2=4.030e-7  CJO=4.940e-9  M=1.779  VJ=2.661e1)
Dbody   s2   21   DBODY
.MODEL DBODY D   (IS=2.036e-12   N=9.539e-1  RS=4.000e-8  EG=1.120  TT=20n   TRS1=-1.000e-3)
Rdiode  d1   21   9.056e-2  TC=-1.860e-3,1e-4
.MODEL  sw   NMOS(VTO=0  KP=10   LEVEL=1)
Maux    g2   c    a     a    sw
Maux2   b    d    g2    g2   sw
Eaux    c    a    d2    g2   1
Eaux2   d    g2   d2    g2   -1
Cox     b    d2   1.920e-9
.MODEL  DGD   D(CJO=1.920e-9   M=1.908   VJ=8.452)
Rpar    b    d2   10Meg
Dgd     a    d2   DGD
Rpar2   d2   a    10Meg
Cgs     g2   s2   4.306e-9
.ENDS PJQ5538S6VC-AU
*$
